.子程序 文本模块_取文本中间_位置, 文本型, 公开, 根据 取文本中间（） 推导出的一个命令，这是根据前后两个字符所在位置，直接把他们取出来 注意：需注意位置是否需要加1或减1,因为操作的是位置，且没有取文本长度

.参数 参数文本, 文本型

.参数 参数开始位置, 整数型, , 1为首位置，2为第2个位置，如此类推。

.参数 参数结束位置, 整数型

.局部变量 局变结果文本, 文本型

.如果真 (参数开始位置 ＝ -1 或 参数结束位置 ＝ -1)

    ' 调试输出 (“模块_取文本中间_根据位置”, 参数文本, 参数开始位置, 参数结束位置)

    返回 (“”)

.如果真结束

局变结果文本 ＝ 取文本中间 (参数文本, 参数开始位置, 参数结束位置 － (参数开始位置 － 1))  ' 开始位置也算一位

返回 (局变结果文本)

.子程序 文本模块_取整行文本, 文本型, 公开, _根据所在数值 ，得到数值为-1的话，返回空“”| 注意：用寻找文本或倒找文本来取值，防止撮在换行符尾部或不存在的字符位置引起异常  

.参数 参数之原文本, 文本型

.参数 参数之得到数值, 整数型

.局部变量 局变开始位置, 整数型

.局部变量 局变结束位置, 整数型

.局部变量 最终返回, 文本型

.如果真 (参数之得到数值 ＝ -1)

    ' 调试输出 (“文本模块_取整行文本_根据所在数值”, 参数之得到数值)

    返回 (“”)

.如果真结束

局变开始位置 ＝ 倒找文本 (参数之原文本, #换行符, 参数之得到数值, 假)  ' 往左寻找

.如果 (局变开始位置 ＝ -1)  ' 说明在第一行啦

    局变开始位置 ＝ 1  ' 1为首位置

.否则

    局变开始位置 ＝ 局变开始位置 ＋ 2  ' 将开始位置定位回这行首

.如果结束

局变结束位置 ＝ 寻找文本 (参数之原文本, #换行符, 参数之得到数值, 假)  ' 往右寻找

.如果 (局变结束位置 ＝ -1)

    局变结束位置 ＝ 取文本长度 (参数之原文本)  ' 得到最后的数值

.否则

    局变结束位置 ＝ 局变结束位置 － 1  ' 定位到换行符前一格

.如果结束

最终返回 ＝ 文本模块_取文本中间_位置 (参数之原文本, 局变开始位置, 局变结束位置)

返回 (最终返回)